;
; Note: This example will not run with Version 4.1 or earlier of NCL.
;       If you are licensed for version 4.1 of NCAR Graphics and are
;       interested in getting a *test* version of NCL that will work with 
;       this example, send email to ncargfx@ucar.edu.
;
;       This example makes use of the GSUN functions and procedures for
;       generating graphics.  If you would like more information on GSUN,
;       go to the URL:  http://ngwww.ucar.edu/ngdoc/ng/ug/ncl/gsun/
;
   
load "$NCARG_ROOT/lib/ncarg/nclex/gsun/gsn_code.ncl"  ; Load the NCL file
                                                      ; that contains the gsn_*
                                                      ; functions used below.
begin
  wks = gsn_open_wks("x11","example3")  ; Open an X11 window.

;
; Change the color map.
;
  setvalues wks
    "wkColorMap" : (/"white","black","Navy","Gray75","RoyalBlue"/)
  end setvalues

  mpres                        = True        ; Var to hold map plot resources.
  mpres@mpFillOn               = True        ; Turn on fill for map areas.
  mpres@mpLandFillColor        = "Gray75"    ; Land is gray.
  mpres@mpOceanFillColor       = "RoyalBlue" ; Water is blue.
  mpres@mpInlandWaterFillColor = "RoyalBlue" ; Inland water is blue.
  mpres@mpGridLineColor        = "Navy"    ; Grid lines are dark gray.


  txres               = True              ; Var to hold text resources.
  txres@txFontHeightF = 0.02              ; Change text size.
  txres@txFont        = "helvetica-bold"  ; Change font size.
;
; Next two calls draw text strings in NDC space.
;
  gsn_text_ndc(wks,"Water is RoyalBlue, land is Gray75,",0.5,0.88,txres)
  gsn_text_ndc(wks,           "and grid lines are Navy.",0.5,0.84,txres)

  map = gsn_map(wks,"Orthographic",mpres) ; Draw a filled map plot. Frame is 
                                          ; advanced by gsn_map.
end